허세원

-- 설명용 재구성: 아이템 UPDATE 경로만 표현
-- @ItemJson은 프로시저 입력 파라미터를 가정합니다.
-- 원본 프로시저 전체 또는 즉시 실행용 스크립트가 아닙니다.
SET XACT_ABORT ON;

DECLARE @JsonTable TABLE
(
    ItemUniqueID   BIGINT,
    ItemTemplateID INT,
    StackCount     INT,
    DBFlag         INT,
    PrevStackCount INT
);

DECLARE @ExpectedCount INT;
DECLARE @AppliedCount  INT;

BEGIN TRY
    BEGIN TRANSACTION;

    -- 1. JSON 입력을 자료형이 지정된 행 집합으로 변환
    INSERT INTO @JsonTable
    SELECT ItemUniqueID, ItemTemplateID,
           StackCount, DBFlag, PrevStackCount
    FROM OPENJSON(@ItemJson)
    WITH
    (
        ItemUniqueID   BIGINT '$.uid',
        ItemTemplateID INT    '$.tid',
        StackCount     INT    '$.sc',
        DBFlag         INT    '$.flag',
        PrevStackCount INT    '$.psc'
    );

    -- 2. 변경 대상으로 전달된 입력 건수
    SELECT @ExpectedCount = COUNT(*)
    FROM @JsonTable
    WHERE DBFlag = 2;

    -- 3. 서버가 전달한 이전 값과 DB 현재 값이 같을 때만 변경
    UPDATE A
    SET A.StackCount = B.StackCount
    FROM dbo.TItem A
    JOIN @JsonTable B
        ON A.ItemUniqueID = B.ItemUniqueID
       AND A.StackCount = B.PrevStackCount
    WHERE B.DBFlag = 2;

    SET @AppliedCount = @@ROWCOUNT;

    -- 4. 입력 대비 누락을 감지하고 전체 변경을 되돌림
    IF @AppliedCount <> @ExpectedCount
        THROW 50000, N'입력 건수와 변경 건수가 다릅니다.', 1;

    COMMIT TRANSACTION;
END TRY
BEGIN CATCH
    IF XACT_STATE() <> 0
        ROLLBACK TRANSACTION;
    THROW;
END CATCH;